ph传感器、酸碱传感器、Arduino、技术参数、连线图、示例代码

概述

还在为没有一款价格低廉、使用方便的pH计而发愁吗？我们推出了一款专门为Arduino控制器设计的模拟pH计，具有连线简单、方便实用等特点。板载电源指示灯、BNC接口和PH2.0接口。使用时，将pH传感器接到板载BNC接口，将板载PH2.0接口连接到Arduino控制器的模拟口，通过程序控制，您可以非常方便的测量溶液的pH值。
传感器的电极采用玻璃电极和参比电极组合在一起的塑壳不可填充式复合电极，是PH计测量元件，用来测量水溶液中的氢离子活度，即PH值。
该传感器附带黑色厚实包装盒，内附黑色优质海绵垫，不仅充分保护元器件，而且大方美观，附送PH复合电极使用说明书。

注意：为保证测量精度，建议使用校准液对pH计定期校准，以防止出现较大误差。一般半年校准一次，如果测量的溶液中含有较多杂质，建议增加校准次数！

技术指标

模块电源：+5.00V
模块尺寸：43mm×32mm
测量范围：0-14PH
测量温度：0-60℃
精度：±0.1pH(25℃)
响应时间：≤1min
BNC接口型pH传感器
PH2.0接口(3脚贴片)
增益调节电位器
电源指示灯

pH电极特性

该映射表仅为探头电压输出，非模拟端电压输出。
电极输出为毫伏级，与pH值的关系如下(25℃)：

pH计的使用

连接图

使用步骤

注意：

请使用外接开关电源，使电压尽量接近+5.00V，电压越准，精度越高！
电极在每次连续使用前均需要使用标准缓冲溶液进行校正，为取得更正确的结果，环境温度最好在25℃左右，已知PH值要可靠，而且其PH值愈接近被测值愈好。如您测量的样品为酸性，请使用PH4.00的缓冲溶液对电极进行校正，如果您测量的样品为碱性，请使用PH9.18缓冲溶液对电极进行校正。分段进行校准，只是为了获得更好的精度。
pH电极每测一种pH不同的溶液，都需要使用清水清洗，建议使用去离子水清洗。
为保证测量精度，建议使用校准液对pH计定期校准，以防止出现较大误差。一般半年校准一次，如果测量的溶液中含有较多杂质，建议增加校准次数！

**(1)**将各个设备按照图示方式连接，即：pH电极连接到pH meter电路板的BNC接口，然后用模拟连接线，将pH meter电路板连接到Arduino主控器的模拟口2。对Arduino主控器供电后，可以看到pH meter电路板的蓝色指示灯变亮。

**(2)**对Arduino主控器烧写样例代码。

**(3)**将pH电极插入到pH值为7.00的标准溶液中，或者直接短接BNC接口的两个输入，打开Arduino IDE的串口监视器，可以看到当前打印出的pH值，误差不会超过0.3。记录下此时打印的值，然后与7.00相比，把差值修改到程序中的Offset处（差值 = 标准值(7.0) - 打印值）。比如，打印出的pH值为6.88，则差值为0.12，则在样例程序中把#define Offset 0.00改成#define Offset 0.12。

**(4)**将pH电极插入pH值为4.00的校准液中，等待一分钟后，调整增益电位器，使打印出的pH值尽量稳定在4.00左右。此时，酸性段校准已经完成，您可以测试酸性溶液的pH值。

注意:测量其他溶液时，必须清洗电极。

**(5)**依靠pH电极自身的线性特性，经过以上的校准，可以直接测量碱性溶液的pH值，但如果您想获得更好的精度，建议重新校准。碱性段校准采用pH值为9.18的标准液，同样是调节增益电位器，使之稳定在9.18左右。经过校准，此时您可以测量碱性溶液的pH值了。

样例代码

下载样例代码后，打开Arduino IDE的串口监视器，即可看到结果。

/*
 # This sample code is used to test the pH meter V1.0.
 # Editor : YouYou
 # Ver    : 1.0
 # Product: analog pH meter
 # SKU    : SEN0161
*/
#define SensorPin A2            //pH meter Analog output to Arduino Analog Input 0
#define Offset 0.00            //deviation compensate
#define LED 13
#define samplingInterval 20
#define printInterval 800
#define ArrayLenth  40    //times of collection
int pHArray[ArrayLenth];   //Store the average value of the sensor feedback
int pHArrayIndex=0;
void setup(void)
{
  pinMode(LED,OUTPUT);
  Serial.begin(9600);
  Serial.println("pH meter experiment!");    //Test the serial monitor
}
void loop(void)
{
  static unsigned long samplingTime = millis();
  static unsigned long printTime = millis();
  static float pHValue,voltage;
  if(millis()-samplingTime > samplingInterval)
  {
      pHArray[pHArrayIndex++]=analogRead(SensorPin);
      if(pHArrayIndex==ArrayLenth)pHArrayIndex=0;
      voltage = avergearray(pHArray, ArrayLenth)*5.0/1024;
      pHValue = 3.5*voltage+Offset;
      samplingTime=millis();
  }
  if(millis() - printTime > printInterval)   //Every 800 milliseconds, print a numerical, convert the state of the LED indicator
  {
    Serial.print("Voltage:");
        Serial.print(voltage,2);
        Serial.print("    pH value: ");
    Serial.println(pHValue,2);
        digitalWrite(LED,digitalRead(LED)^1);
        printTime=millis();
  }
}
double avergearray(int* arr, int number){
  int i;
  int max,min;
  double avg;
  long amount=0;
  if(number<=0){
    Serial.println("Error number for the array to avraging!/n");
    return 0;
  }
  if(number<5){   //less than 5, calculated directly statistics
    for(i=0;i<number;i++){
      amount+=arr[i];
    }
    avg = amount/number;
    return avg;
  }else{
    if(arr[0]<arr[1]){
      min = arr[0];max=arr[1];
    }
    else{
      min=arr[1];max=arr[0];
    }
    for(i=2;i<number;i++){
      if(arr[i]<min){
        amount+=min;        //arr<min
        min=arr[i];
      }else {
        if(arr[i]>max){
          amount+=max;    //arr>max
          max=arr[i];
        }else{
          amount+=arr[i]; //min<=arr<=max
        }
      }//if
    }//for
    avg = (double)amount/(number-2);
  }//if
  return avg;
}

Mind+(基于Scratch3.0)图形化编程

1、下载及安装软件。下载地址：https://www.mindplus.cc 详细教程：Mind+基础wiki教程-软件下载安装
2、切换到“上传模式”。详细教程：Mind+基础wiki教程-上传模式编程流程
3、“扩展”中选择“主控板”中的“Arduino Uno”，“传感器”中加载“模拟PH计”。详细教程：Mind+基础wiki教程-加载扩展库流程
4、进行编程，程序如下图：
5、菜单“连接设备”，“上传到设备”
6、程序上传完毕后，打开串口即可看到数据输出。详细教程：Mind+基础wiki教程-串口打印

结果

打开串口监视器，将波特率调整到9600，在串口中可以读取PH计所测水源的PH值。

维护及注意事项

电极在初次使用或久置不用重新使用时，把电极球泡及砂芯，浸在3NKCL溶液中活化8小时。
取下电极保护套后要注意，在塑料保护栅内的敏感玻璃泡不与硬物接触，任何破损和擦毛都会使电极失效。
测量完毕，不用时应将电极保护套套上，保护套内应放少量3.3mol/L氯化钾溶液，以保持电极球泡的湿润。
电极的引出端，必须保持清洁和干燥，绝对防止输出两端短路，否则将导致测量结果失准或失效。
电极避免长期浸在蒸馏水中或蛋白质溶液和酸性氯化物溶液中，并防止和有机硅油脂接触。
电极经长期使用后，如发现梯度略有降低，则可把电极下端浸泡在4%HF（氢氟酸）中3-5秒钟，用蒸馏水洗净，然后在氯化钾溶液中浸泡，使之复新。
被测溶液中如含有易污染敏感球泡货堵塞液接界的物质，而使电极钝化，其现象是敏感梯度降低，货读数不准。如此，则应根据污染物质的性质，以适当溶液清洗，使之复新。
选用清洗剂时，如能溶解聚碳酸树脂的清洗液，如四氯化碳，三氯乙烯，四氢呋喃等，则可能把聚碳酸树脂溶解后，涂在敏感玻璃球泡上，而使电极失效，请慎用！

概述