产品简介

Gravity：10轴惯性测量单元传感器精妙融合了3轴加速度计、陀螺仪、磁力计与气压传感器，可实现高精度运动检测与动态空间定位。该传感器支持I2C通信，并配备开源的Arduino和Python库，非常适合快速原型开发与灵活集成。其全面的功能使其广泛应用于可穿戴设备、智能手表、物联网设备、无人机及环境监测等领域。无论是工程师还是爱好者，Gravity传感器都能为前沿项目提供所需的精度与适应性。您可以通过教程、项目案例等资源，将该传感器深度融入您的创新设计之中。

产品参数

基本参数

加速度参数

陀螺仪参数

地磁参数

气压参数

物理尺寸

尺寸图

单位：mm

引脚说明

I2C地址设置开关说明

注意事项：

• “I2C/UART切换开关”的切换可以断电保存，重启设备后新模式生效。

Arduino IDE 使用教程

说明：本传感器支持任意运动、无运动、显著运动等多种运动状态检测，以及敲击、倾斜、方向、平面检测等手势识别功能。Wiki 仅展示核心基础用法，更多运动状态检测与高级功能实现，请直接参考库文件中完整的 examples 示例程序及API，此处不再逐一展开。

通过I2C读取数据的ESP32示例代码

目标

本教程旨在演示如何初始化10轴IMU传感器，并通过轮询方式直接读取加速度、角速度、地磁和气压数据。

硬件准备

• DFR1222 FireBeetle 2 ESP32-C5 ×1
• SEN0696 Gravity: BMI323+BMM350+BMP581 10 DOT传感器×1

软件准备

• 下载并安装 Arduino IDE：下载 Arduino IDE
• 下载并安装 DFRobot_Multi_DOF_IMU 库：下载 DFRobot_Multi_DOF_IMU 库
• 下载并安装 DFRobot_RTU 库：下载 DFRobot_RTU 库
• 库安装指南：查看安装指南

接线配置

• 按图示连接 传感器与 ESP32-C5，核心对应关系：
  • 传感器引脚 “+” → ESP32-E 3.3V
  • 传感器引脚 “-” → ESP32-E GND
  • 传感器 I2C 引脚 “SCL” → ESP32-E SCL（默认 GPIO10）
  • 传感器 I2C 引脚 “SDA” → ESP32-E SDA（默认 GPIO9）
  • 传感器拨码开关配置：通信模式拨到I2C侧，I2C地址拨到0x4A（A0=0，A1=0）

样例代码

#include "DFRobot_Multi_DOF_IMU.h"

#define IMU_COMM_I2C
// 是否计算海拔高度（true=海拔，false=气压）
const bool CALCULATE_ALTITUDE = true;

const uint8_t IMU_ADDR = 0x4A;

// 初始化I2C通信的IMU对象
DFRobot_Multi_DOF_IMU_I2C imu(DFRobot_Multi_DOF_IMU::eSensorModel10DOF, &Wire, IMU_ADDR);

void setup() {
  Serial.begin(115200);
  while (!Serial) {
    delay(10);
  }

  Serial.println("\n10DOF IMU Simplified Data Reading (ESP32 I2C)\n");

  // 初始化传感器
  Serial.print("Initializing IMU sensor... ");
  while (!imu.begin()) {
    Serial.println("Failed! Check address and wiring.");
    delay(1000);
  }
  Serial.println("Success!");

  // 基础配置（传感器模式、加速度计、陀螺仪量程）
  imu.setSensorMode(DFRobot_Multi_DOF_IMU::eNormalMode);
  imu.setAccelRange(DFRobot_Multi_DOF_IMU::eAccelRange2G);
  imu.setGyroRange(DFRobot_Multi_DOF_IMU::eGyroRange250DPS);

  // 海拔校准（参考海拔540米，可根据实际修改）
  if (CALCULATE_ALTITUDE) {
    Serial.print("Calibrating altitude (reference: 540m)... ");
    imu.calibrateAltitude(540.0);
    Serial.println("Done");
  }

  Serial.println("\nConfiguration completed. Starting data reading...\n");
  delay(500);
}

void loop() {
  // 定义存储传感器数据的变量
  DFRobot_Multi_DOF_IMU::sSensorData_t accelData, gyroData, magData;
  float pressureAltValue; // 存储气压(Pa)或海拔(m)

  // 读取10DOF传感器数据
  if (imu.get10dofData(&accelData, &gyroData, &magData, &pressureAltValue, CALCULATE_ALTITUDE)) {
    Serial.println("==================== IMU Data ====================");
    
    // 加速度计数据（Accelerometer）
    Serial.println("--- Accelerometer Data (g) ---");
    Serial.print("X-axis: "); Serial.print(accelData.x, 3); Serial.println(" g");
    Serial.print("Y-axis: "); Serial.print(accelData.y, 3); Serial.println(" g");
    Serial.print("Z-axis: "); Serial.print(accelData.z, 3); Serial.println(" g");

    // 陀螺仪数据（Gyroscope）
    Serial.println("--- Gyroscope Data (dps) ---");
    Serial.print("X-axis: "); Serial.print(gyroData.x, 2); Serial.println(" dps");
    Serial.print("Y-axis: "); Serial.print(gyroData.y, 2); Serial.println(" dps");
    Serial.print("Z-axis: "); Serial.print(gyroData.z, 2); Serial.println(" dps");

    // 磁力计数据（Magnetometer）
    Serial.println("--- Magnetometer Data (uT) ---");
    Serial.print("X-axis: "); Serial.print(magData.x, 2); Serial.println(" uT");
    Serial.print("Y-axis: "); Serial.print(magData.y, 2); Serial.println(" uT");
    Serial.print("Z-axis: "); Serial.print(magData.z, 2); Serial.println(" uT");

    // 气压/海拔数据
    if (CALCULATE_ALTITUDE) {
      Serial.println("--- Altitude Data ---");
      Serial.print("Altitude: "); Serial.print(pressureAltValue, 2); Serial.println(" meters");
    } else {
      Serial.println("--- Pressure Data ---");
      Serial.print("Pressure: "); Serial.print(pressureAltValue, 2); Serial.println(" Pa");
      Serial.print("Pressure (hPa): "); Serial.print(pressureAltValue / 100.0, 2); Serial.println(" hPa");
    }
    Serial.println("===================================================\n");
  } else {
    Serial.println("Error: Failed to read IMU sensor data!\n");
  }
  delay(500);
}

结果

通过UART与中断读取数据的ESP32示例代码

目标

本教程旨在演示如何配置9轴IMU传感器，在数据就绪时通过硬件中断触发，并在中断服务程序中读取加速度、角速度和地磁数据，实现高效的数据采集。

硬件准备

• DFR1222 FireBeetle 2 ESP32-C5 ×1
• SEN0696 Gravity: BMI323+BMM350+BMP581 10 DOT传感器×1

软件准备

• 下载并安装 Arduino IDE：下载 Arduino IDE
• 下载并安装 DFRobot_Multi_DOF_IMU 库：下载 DFRobot_Multi_DOF_IMU 库
• 下载并安装 DFRobot_RTU 库：下载 DFRobot_RTU 库
• 库安装指南：查看安装指南

接线配置

• 按图示连接10轴IMU传感器与 ESP32-C5，核心对应关系：
  • 传感器引脚 “+” → ESP32-C5 3.3V
  • 传感器引脚 “-” → ESP32-C5 GND
  • 传感器引脚“INT1” → ESP32-C5 GPIO27
  • 传感器引脚“INT3” → ESP32-C5 GPIO28
  • 传感器引脚“INT4” → ESP32-C5 GPIO25
  • 传感器 UART 引脚 “RX” → ESP32-C5 D3（GPIO26）
  • 传感器 UART 引脚 “TX” → ESP32-C5 D2（GPIO8）
  • 传感器拨码开关配置：通信模式拨到UART侧，地址拨到0x4A（A0=0，A1=0）

样例代码

#include "DFRobot_Multi_DOF_IMU.h"
#define IMU_COMM_UART

#undef CALIBRATE_ABSOLUTE_DIFFERENCE
const bool CALCULATE_ALTITUDE = false;

const uint8_t ADDR = 0x4A;


DFRobot_Multi_DOF_IMU_UART imu(DFRobot_Multi_DOF_IMU::eSensorModel10DOF, &Serial1, 9600, ADDR, /*rx=*/8, /*tx=*/26);

volatile bool int1DataReady = false;
volatile bool int3DataReady = false;
volatile bool int4DataReady = false;

// INT1数据就绪中断服务函数
void IRAM_ATTR int1ISR() {
  int1DataReady = true;
}

// INT3数据就绪中断服务函数
void IRAM_ATTR int3ISR() {
  int3DataReady = true;
}

// INT4数据就绪中断服务函数
void IRAM_ATTR int4ISR() {
  int4DataReady = true;
}

void setup() {
  // 初始化串口监视器（波特率115200）
  Serial.begin(115200);
  while (!Serial) delay(10);

  // [1] 初始化传感器
  Serial.print("\n[1] Initializing sensor... ");
  while (!imu.begin()) {
    Serial.println("Failed, please check device address and connections!");
    delay(1000);
  }
  Serial.println("Success");
  delay(500);

  // [2] 设置传感器为正常模式
  Serial.print("[2] Setting sensor mode to normal... ");
  while (!imu.setSensorMode(DFRobot_Multi_DOF_IMU::eNormalMode)) {
    Serial.println("Failed, please check device communication!");
    delay(1000);
  }
  Serial.println("Success");
  delay(500);

  // [3] 设置加速度计量程为±2G
  Serial.print("[3] Setting accelerometer range to ±2G... ");
  while (!imu.setAccelRange(DFRobot_Multi_DOF_IMU::eAccelRange2G)) {
    Serial.println("Failed, please check device communication!");
    delay(1000);
  }
  Serial.println("Success");
  delay(500);

  // [4] 设置陀螺仪量程为±250dps
  Serial.print("[4] Setting gyroscope range to ±250dps... ");
  while (!imu.setGyroRange(DFRobot_Multi_DOF_IMU::eGyroRange250DPS)) {
    Serial.println("Failed, please check device communication!");
    delay(1000);
  }
  Serial.println("Success");
  delay(500);



  // [5] 配置INT1数据就绪中断
  Serial.print("[5] Configuring INT1 data ready interrupt... ");
  while (!imu.setInt(DFRobot_Multi_DOF_IMU::eImuIntPin1, DFRobot_Multi_DOF_IMU::eInt1_2DataReady)) {
    Serial.println("Failed, please check pin and interrupt configuration!");
    delay(1000);
  }
  Serial.println("Success");
  delay(500);

  // [6] 配置INT3数据就绪中断
  Serial.print("[6] Configuring INT3 data ready interrupt... ");
  while (!imu.setInt(DFRobot_Multi_DOF_IMU::eImuIntPin3, DFRobot_Multi_DOF_IMU::eInt3DataReady)) {
    Serial.println("Failed, please check pin and interrupt configuration!");
    delay(1000);
  }
  Serial.println("Success");
  delay(500);

  // [7] 配置INT4数据就绪中断
  Serial.print("[7] Configuring INT4 data ready interrupt... ");
  while (!imu.setInt(DFRobot_Multi_DOF_IMU::eImuIntPin4, DFRobot_Multi_DOF_IMU::eInt4DataReady)) {
    Serial.println("Failed, please check pin and interrupt configuration!");
    delay(1000);
  }
  Serial.println("Success");
  delay(500);

  // [8] 配置ESP32-C5外部中断（INT1→GPIO27，INT3→GPIO28，INT4→GPIO25，上升沿触发）
  Serial.print("[8] Configuring Arduino interrupt pins... ");
  attachInterrupt(digitalPinToInterrupt(27), int1ISR, RISING);
  attachInterrupt(digitalPinToInterrupt(28), int3ISR, RISING);
  attachInterrupt(digitalPinToInterrupt(25), int4ISR, RISING);
  Serial.println("Success");
  Serial.println("Trigger mode: Rising edge");

  // 配置完成提示
  Serial.println("\nConfiguration complete, starting data reading");
  delay(100);
}

void loop() {
  if (int1DataReady || int3DataReady || int4DataReady) {
    if (int1DataReady && int3DataReady && int4DataReady) {
      int1DataReady = false;
      int3DataReady = false;
      int4DataReady = false;

      DFRobot_Multi_DOF_IMU::sSensorData_t accel, gyro, mag;
      float pressureValue; // 固定为压力(Pa)

      if (imu.get10dofData(&accel, &gyro, &mag, &pressureValue, CALCULATE_ALTITUDE)) {
        
        Serial.println("--- New Data ---");
        Serial.print("AccX (g): "); Serial.println(accel.x, 3);
        Serial.print("AccY (g): "); Serial.println(accel.y, 3);
        Serial.print("AccZ (g): "); Serial.println(accel.z, 3);
        Serial.print("GyrX (dps): "); Serial.println(gyro.x, 2);
        Serial.print("GyrY (dps): "); Serial.println(gyro.y, 2);
        Serial.print("GyrZ (dps): "); Serial.println(gyro.z, 2);
        Serial.print("MagX (uT): "); Serial.println(mag.x, 2);
        Serial.print("MagY (uT): "); Serial.println(mag.y, 2);
        Serial.print("MagZ (uT): "); Serial.println(mag.z, 2);
  
        Serial.print("Pressure (Pa): "); 
        Serial.println(pressureValue, 2);
        Serial.println(" ");
      } else {
        Serial.println("Failed to read 10DOF data!");
      }
    }
  }
  delay(200);
}

结果

API函数

 /**
   * @fn begin
   * @brief 初始化UART通信和传感器
   * @return bool
   * @retval true  初始化成功
   * @retval false 初始化失败
   */
  bool begin(void);

  /**
   * @fn setSensorMode
   * @brief 设置传感器工作模式
   * @param mode 传感器工作模式（参见 eSensorMode_t）
   * @n 可用模式：
   * @n - eSleepMode:           睡眠模式（最低功耗，传感器停止工作）
   * @n - eLowPowerMode:        低功耗模式（降低采样率，节省功耗）
   * @n - eNormalMode:          正常模式（平衡功耗和性能）
   * @n - eHighPerformanceMode: 高性能模式（最高采样率和精度，功耗最高）
   * @return bool
   * @retval true  设置成功
   * @retval false 设置失败
   */
  bool setSensorMode(eSensorMode_t mode);

  /**
   * @fn reset
   * @brief 恢复出厂设置
   * @return bool
   * @retval true  恢复出厂设置成功
   * @retval false 恢复出厂设置失败
   */
  bool reset(void);

  /**
   * @fn setAccelRange
   * @brief 设置加速度计量程
   * @param range 加速度计量程（参见 eAccelRange_t）
   * @n 可用量程：
   * @n - eAccelRange2G:  ±2g 量程
   * @n - eAccelRange4G:  ±4g 量程
   * @n - eAccelRange8G:  ±8g 量程
   * @n - eAccelRange16G: ±16g 量程
   * @return bool
   * @retval true  设置成功
   * @retval false 设置失败
   */
  bool setAccelRange(eAccelRange_t range);

  /**
   * @fn setGyroRange
   * @brief 设置陀螺仪量程
   * @param range 陀螺仪量程（参见 eGyroRange_t）
   * @n 可用量程：
   * @n - eGyroRange125DPS:  ±125dps 量程
   * @n - eGyroRange250DPS:  ±250dps 量程
   * @n - eGyroRange500DPS:  ±500dps 量程
   * @n - eGyroRange1000DPS: ±1000dps 量程
   * @n - eGyroRange2000DPS: ±2000dps 量程
   * @return bool
   * @retval true  设置成功
   * @retval false 设置失败
   */
  bool setGyroRange(eGyroRange_t range);

  /**
   * @fn get6dofData
   * @brief 读取6轴IMU数据（物理量）
   * @param accel 指向sSensorData_t结构的指针，用于存储加速度数据（单位：g）
   * @param gyro 指向sSensorData_t结构的指针，用于存储陀螺仪数据（单位：dps）
   * @return bool
   * @retval true  读取成功
   * @retval false 读取失败
   */
  bool get6dofData(sSensorData_t *accel, sSensorData_t *gyro);

  /**
   * @fn get9dofData
   * @brief 读取9轴IMU数据（物理量）
   * @param accel 指向sSensorData_t结构的指针，用于存储加速度数据（单位：g）
   * @param gyro 指向sSensorData_t结构的指针，用于存储陀螺仪数据（单位：dps）
   * @param mag 指向sSensorData_t结构的指针，用于存储磁力计数据（单位：uT）
   * @return bool
   * @retval true  读取成功
   * @retval false 读取失败
   */
  bool get9dofData(sSensorData_t *accel, sSensorData_t *gyro, sSensorData_t *mag);

  /**
   * @fn get10dofData
   * @brief 读取10轴IMU数据（物理量）
   * @param accel 指向sSensorData_t结构的指针，用于存储加速度数据（单位：g）
   * @param gyro 指向sSensorData_t结构的指针，用于存储陀螺仪数据（单位：dps）
   * @param mag 指向sSensorData_t结构的指针，用于存储磁力计数据（单位：uT）
   * @param pressure 指向float类型的指针，用于存储气压或海拔高度数据
   * @param calcAltitude 是否计算海拔高度，默认为false
   * @n true: pressure存储海拔高度（单位：m）
   * @n false: pressure存储气压数据（单位：Pa）
   * @return bool
   * @retval true  读取成功
   * @retval false 读取失败
   */
  bool get10dofData(sSensorData_t *accel, sSensorData_t *gyro, sSensorData_t *mag, float *pressure, bool calcAltitude = false);

  /**
   * @fn calibrateAltitude
   * @brief 根据当地海拔高度校准海拔数据
   * @param altitude 当地海拔高度（单位：m）
   * @n 例如：540.0 表示海拔540米
   * @n 调用此函数后，get10dofData 中请求海拔时（calcAltitude 为 true）将使用该校准消除绝对误差
   * @return bool
   * @retval true  校准成功（海拔高度 > 0）
   * @retval false 校准失败（海拔高度 <= 0）
   */
  bool calibrateAltitude(float altitude);

  /**
   * @fn setPressOOR
   * @brief 配置气压超出范围(OOR)参数
   * @param threshold 气压阈值（单位：Pa）
   * @param range 允许范围（单位：Pa）
   * @n 实际允许范围：threshold - range ~ threshold + range
   * @param countLimit 计数限制（参见 ePressOORCountLimit_t）
   * @n 连续N次超出范围后才触发中断，用于滤波避免误触发
   * @n 可用值：
   * @n - ePressOORCountLimit1:  连续1次超出范围后触发
   * @n - ePressOORCountLimit3:  连续3次超出范围后触发
   * @n - ePressOORCountLimit7:  连续7次超出范围后触发
   * @n - ePressOORCountLimit15: 连续15次超出范围后触发
   * @return bool
   * @retval true  配置成功
   * @retval false 配置失败
   */
  bool setPressOOR(uint32_t threshold, uint8_t range, ePressOORCountLimit_t countLimit);

  /**
   * @fn setInt
   * @brief 配置中断（统一API）
   * @param pin 中断引脚（参见 eImuIntPin_t）
   * @n 可用引脚：
   * @n - eImuIntPin1: INT1引脚（6轴传感器，支持多种中断类型）
   * @n - eImuIntPin2: INT2引脚（6轴传感器，支持多种中断类型）
   * @n - eImuIntPin3: INT3引脚（9轴传感器-磁力计，仅支持数据就绪中断）
   * @n - eImuIntPin4: INT4引脚（10轴传感器-气压计，支持数据就绪和气压OOR中断）
   * @param intType 中断类型（uint8_t）
   * @n INT1/INT2支持的中断类型（eInt1_2Type_t）：
   * @n - eInt1_2Disable (0x00): 禁用中断
   * @n - eInt1_2DataReady (0x01): 数据就绪中断
   * @n - eInt1_2AnyMotion (0x02): 任意运动中断
   * @n - eInt1_2NoMotion (0x03): 无运动中断
   * @n - eInt1_2SigMotion (0x04): 显著运动中断
   * @n - eInt1_2StepCounter (0x05): 步进计数中断
   * @n - eInt1_2Flat (0x06): 平面中断
   * @n - eInt1_2Orientation (0x07): 方向中断
   * @n - eInt1_2Tap (0x08): 敲击中断
   * @n - eInt1_2Tilt (0x09): 倾斜中断
   * @n INT3支持的中断类型（eInt3Type_t）：
   * @n - eInt3Disable (0x00): 禁用中断
   * @n - eInt3DataReady (0x01): 数据就绪中断
   * @n INT4支持的中断类型（eInt4Type_t）：
   * @n - eInt4Disable (0x00): 禁用中断
   * @n - eInt4DataReady (0x01): 数据就绪中断
   * @n - eInt4PressureOOR (0x02): 气压超出范围中断
   * @return bool
   * @retval true  配置成功
   * @retval false 配置失败
   */
  bool setInt(eImuIntPin_t pin, uint8_t intType);

  /**
   * @fn getIntStatus
   * @brief 读取中断状态（统一API）
   * @param pin 中断引脚（参见 eImuIntPin_t）
   * @return uint16_t 中断状态
   * @n 可与相应的中断状态宏进行按位与操作来判断中断类型
   * @retval 0 无中断或读取失败
   */
  uint16_t getIntStatus(eImuIntPin_t pin);

  /**
   * @fn getStepCount
   * @brief 读取步数计数器数据
   * @details 读取当前累计步数
   * @n 检测到步进中断后，调用此函数读取累计步数
   * @return uint32_t 累计步数（32位）
   * @retval 0 无步数数据或读取失败
   */
  uint32_t getStepCount(void);

  /**
   * @fn getTap
   * @brief 读取敲击数据
   * @details 当检测到敲击中断后，调用此函数读取具体的敲击类型
   * @return uint16_t 敲击数据
   * @n 返回值：
   * @n - TAP_TYPE_SINGLE (0x0001): 单击
   * @n - TAP_TYPE_DOUBLE (0x0002): 双击
   * @n - TAP_TYPE_TRIPLE (0x0003): 三击
   * @retval 0 无敲击数据或读取失败
   */
  uint16_t getTap(void);

  /**
   * @fn getOrientation
   * @brief 读取方向数据
   * @details 当检测到方向中断后，调用此函数读取具体的方向和面部朝向
   * @return uint16_t 方向数据
   * @n 高字节：方向类型
   * @n - ORIENT_TYPE_PORTRAIT_UP (0x01): 竖屏正向
   * @n - ORIENT_TYPE_LANDSCAPE_LEFT (0x02): 横屏向左
   * @n - ORIENT_TYPE_LANDSCAPE_RIGHT (0x03): 横屏向右
   * @n - ORIENT_TYPE_PORTRAIT_DOWN (0x04): 竖屏倒置
   * @n 低字节：朝向类型
   * @n - ORIENT_FACE_UP (0x00): 面向前
   * @n - ORIENT_FACE_DOWN (0x01): 面向后
   * @retval 0 无方向数据或读取失败
   */
  uint16_t getOrientation(void);

上位机使用教程

硬件准备

• TEL0190 RainbowLink V2 ×1
• SEN0696 Gravity:9 DOF IMU Sensor ×1

软件准备

• 下载并解压上位机软件：下载上位机软件

接线配置

• 按图示连接10轴IMU传感器与 RainbowLink V2，核心对应关系：
  • 传感器引脚 “+” → RainbowLink V2 5V
  • 传感器引脚 “-” → RainbowLink V2 GND
  • 传感器 UART 引脚 “RX” → RainbowLink V2 TX
  • 传感器 UART 引脚 “TX” → RainbowLink V2 RX
  • 传感器拨码开关配置：通信模式拨到UART侧，地址拨到0x4A

操作步骤

1. 将 10 轴 IMU 传感器与 RainbowLink V2 正确连接，传感器通信模式拨码开关拨至 UART 侧，地址拨至 0x4A。
2. 打开上位机，在右上方将语言切换为中文模式，选择正确的端口号，设置波特率为默认9600，点击右上方的「打开串口」。
3. 然后摇动传感器3s进行校准，此时界面左侧可显示6轴IMU传感器运动的动态画面。右侧则是加速度、陀螺仪等实时数据。

结果

Modbus 寄存器定义

Modbus-RTU 常用功能代码：

通过以上命令可读写输入寄存器和保持寄存器。

读取加速度三轴数据示例

目标

通过 Modbus RTU 协议读取10轴IMU传感器当前检测到的加速度数值

硬件准备

• TEL0190 RainbowLink V2 ×1
• SEN0696 Gravity:9 DOF IMU Sensor ×1

接线配置

• 按图示连接10轴IMU传感器与 RainbowLink V2，核心对应关系：
  • 传感器引脚 “+” → RainbowLink V2 5V
  • 传感器引脚 “-” → RainbowLink V2 GND
  • 传感器 UART 引脚 “RX” → RainbowLink V2 TX
  • 传感器 UART 引脚 “TX” → RainbowLink V2 RX
  • 传感器拨码开关配置：通信模式拨到UART侧，地址拨到0x4A

通用操作步骤

• 硬件连接：通过 RainbowLink USB 协议转换器，将传感器与主机（电脑）连接，传感器通信模式切换至 UART，地址切换至0x4A
• 参数配置：在串口调试工具中设置参数（需与传感器一致）：
  • 波特率：9600（默认）
  • 数据位：8 位
  • 停止位：1 位
  • 校验位：无
• 发送指令：在调试工具的 “发送区” 输入下述十六进制指令，勾选 “十六进制发送” 后发送。

发送指令及解析

完整发送指令：4A 04 00 06 00 03 5F B1

返回数据及解析

传感器收到指令后返回如下数据（示例）：

完整返回数据：4A 04 06 FF AD FF DD EF E1 B7 E1

数据解析步骤

返回的原始数据 FF AD、FF DD、EF E1 是 16 位有符号整数（补码），需要按以下步骤转换为实际的加速度值（单位：g）。

1. 将十六进制转换为有符号十进制

   • X 轴原始值：FF AD 无符号值 = 0xFFAD = 65453 有符号值 = 65453 − 65536 = -83
   • Y 轴原始值：FF DD 无符号值 = 0xFFDD = 65493 有符号值 = 65493 − 65536 = -43
   • Z 轴原始值：EF E1 无符号值 = 0xEFE1 = 61409 有符号值 = 61409 − 65536 = -4127

2. 根据量程和灵敏度转换为物理值

   BMI323 加速度计的默认量程为 ±8 g，在此量程下灵敏度为 4096 LSB/g（参见规格书第 9 页 Table 3）。

   计算公式：

   加速度 (g)=有符号原始值/灵敏度

   • X 轴：−83/4096≈−0.0203 g
   • Y 轴：−43/4096≈−0.0105 g
   • Z 轴：−4127/4096≈−1.0076 g

3. 结果解读

• X、Y 轴接近 0 g，表明传感器在水平面上无倾斜。
• Z 轴约为 -1 g，表明重力方向为负（传感器正面朝上，Z 轴指向地心）。
• 该数据符合传感器静止时的预期输出。

为什么这样处理？

1. 数字输出：传感器内部将模拟量转换为数字信号，输出为 16 位二进制补码。必须通过规格书定义的灵敏度将其还原为物理量。
2. 量程影响：灵敏度与所选量程相关（不同量程对应不同 LSB/g 值），解析前需确认当前量程设置（默认 ±8 g，若更改需通过保持寄存器 0x0008 读取）。
3. 符号性：加速度有方向，因此采用有符号数表示。补码格式需通过减去 65536 转换为负数。

注意事项

• 若修改了加速度计量程（如 ±2 g、±4 g、±16 g），灵敏度会相应变化，解析公式中的分母需同步调整。
• 返回数据中的 CRC 校验可用于验证传输完整性（本示例中 CRC 正确，数据可靠）。
• 如需连续读取，可直接重复发送相同指令，传感器会返回最新采样值。

更多资料下载

• 原理图

• 元件位置图

• 3D_STP

• 2D_CAD

• 上位机软件

• EMC证书

• ROHS证书