(SKU:DFR0651)TinkerNode Gravity IO扩展板

来自DFRobot Product Wiki
跳转至: 导航搜索

目录

概述

TinkerNode Gravity IO扩展板是一款为TinkerNode物联网开发板系列量身打造的IO扩展板,它扩展了丰富的接口,让你方便地连接各类符合Gravity接口标准的模块,让你摆脱面包板繁杂的连线,项目搭建更加轻松优雅。此外,为了实现物联网场景下,电池供电系统经常遇到的低功耗设计问题,扩展板提供了2路电源控制,可通过数字IO打开或关闭连接在扩展板上外设的供电,让其只在需要的时候通电工作,以最小化系统功耗。

特性

  • TinkerNode物联网开发板系列专用IO扩展
  • Gravity标准接口,繁琐连线瞬间变得轻松简单
  • 外设供电可动态控制,轻松实现系统低功耗


技术规格

  • 丰富的接口扩展
    • Gravity Analog 3P接口:2个
    • Gravity Digital 3P接口:5个
    • Gravity IIC 4P接口:3个
    • Gravity UART 4P接口:1个
    • SPI 6P接口:1个
    • 复位RST 2P接口:1个
    • 电池BAT、5V、3V3供电输出2P接口:各2个
  • 产品尺寸:31×38 mm
  • 重量:8 g


接口说明


DFR0651 overview(CH).png


连接指南

  • 如下图将模块左上角带有白色丝印的一角与底部的主控板对齐,插入即可。


DFR0651 connection.png


使用教程

  • SPI接口使用排母,片选信号SS可通过拨码开关连接到D0~D2中的任意一个。


DFR0651 SPI intro.png


  • SPI接口可直接连接microSD/TF模块,当开发板自身存储空间不足时,外接microSD/TF模块可提供海量数据的存储需要。除了将模块插入SPI接口,需要注意将拨码开关的其中一路拨到ON,以将D0~D2中任意一个IO连接到片选SS,并在代码中对管脚映射作相应修改。


DFR0651 SPI connection.png


  • 如下图,开发板的供电被划分为两块(橘蓝两色框选的区域),并分别通过EN1和EN2进行控制。当EN1和EN2悬空时(内部上拉),GND1和GND2与开发板的系统地GND相连,正常供电。当EN1或EN2通过数字管脚(D0~D4)被拉至低电平时(需要杜邦线连接),GND1或GND2与开发板的系统地GND断开,相对应的供电被断开。通过这种方式,可以将连接到扩展板的外设供电关断,实现外设的间歇工作,以达到低功耗


DFR0651 EN intro(CH).png


应用实例

通过SPI接口读写TF卡

  • 连接:将TF卡插入microSD/TF模块microSD/TF模块如上图插入到扩展板的SPI接口,并将标有D0一路的拨码开关拨到ON位置,并将扩展板插入TinkerNode主板中。
  • 测试代码:将如下代码上传至TinkerNode主板中,进行TF卡的读写测试。
#include "FS.h"
#include "SD.h"
#include "SPI.h"

#define SS D0   // For TinkerNode Series, SS can be one of D0~D2


void listDir(fs::FS &fs, const char * dirname, uint8_t levels){
    Serial.printf("Listing directory: %s\n", dirname);

    File root = fs.open(dirname);
    if(!root){
        Serial.println("Failed to open directory");
        return;
    }
    if(!root.isDirectory()){
        Serial.println("Not a directory");
        return;
    }

    File file = root.openNextFile();
    while(file){
        if(file.isDirectory()){
            Serial.print("  DIR : ");
            Serial.println(file.name());
            if(levels){
                listDir(fs, file.name(), levels -1);
            }
        } else {
            Serial.print("  FILE: ");
            Serial.print(file.name());
            Serial.print("  SIZE: ");
            Serial.println(file.size());
        }
        file = root.openNextFile();
    }
}

void createDir(fs::FS &fs, const char * path){
    Serial.printf("Creating Dir: %s\n", path);
    if(fs.mkdir(path)){
        Serial.println("Dir created");
    } else {
        Serial.println("mkdir failed");
    }
}

void removeDir(fs::FS &fs, const char * path){
    Serial.printf("Removing Dir: %s\n", path);
    if(fs.rmdir(path)){
        Serial.println("Dir removed");
    } else {
        Serial.println("rmdir failed");
    }
}

void readFile(fs::FS &fs, const char * path){
    Serial.printf("Reading file: %s\n", path);

    File file = fs.open(path);
    if(!file){
        Serial.println("Failed to open file for reading");
        return;
    }

    Serial.print("Read from file: ");
    while(file.available()){
        Serial.write(file.read());
    }
    file.close();
}

void writeFile(fs::FS &fs, const char * path, const char * message){
    Serial.printf("Writing file: %s\n", path);

    File file = fs.open(path, FILE_WRITE);
    if(!file){
        Serial.println("Failed to open file for writing");
        return;
    }
    if(file.print(message)){
        Serial.println("File written");
    } else {
        Serial.println("Write failed");
    }
    file.close();
}

void appendFile(fs::FS &fs, const char * path, const char * message){
    Serial.printf("Appending to file: %s\n", path);

    File file = fs.open(path, FILE_APPEND);
    if(!file){
        Serial.println("Failed to open file for appending");
        return;
    }
    if(file.print(message)){
        Serial.println("Message appended");
    } else {
        Serial.println("Append failed");
    }
    file.close();
}

void renameFile(fs::FS &fs, const char * path1, const char * path2){
    Serial.printf("Renaming file %s to %s\n", path1, path2);
    if (fs.rename(path1, path2)) {
        Serial.println("File renamed");
    } else {
        Serial.println("Rename failed");
    }
}

void deleteFile(fs::FS &fs, const char * path){
    Serial.printf("Deleting file: %s\n", path);
    if(fs.remove(path)){
        Serial.println("File deleted");
    } else {
        Serial.println("Delete failed");
    }
}

void testFileIO(fs::FS &fs, const char * path){
    File file = fs.open(path);
    static uint8_t buf[512];
    size_t len = 0;
    uint32_t start = millis();
    uint32_t end = start;
    if(file){
        len = file.size();
        size_t flen = len;
        start = millis();
        while(len){
            size_t toRead = len;
            if(toRead > 512){
                toRead = 512;
            }
            file.read(buf, toRead);
            len -= toRead;
        }
        end = millis() - start;
        Serial.printf("%u bytes read for %u ms\n", flen, end);
        file.close();
    } else {
        Serial.println("Failed to open file for reading");
    }


    file = fs.open(path, FILE_WRITE);
    if(!file){
        Serial.println("Failed to open file for writing");
        return;
    }

    size_t i;
    start = millis();
    for(i=0; i<2048; i++){
        file.write(buf, 512);
    }
    end = millis() - start;
    Serial.printf("%u bytes written for %u ms\n", 2048 * 512, end);
    file.close();
}

void setup(){
    Serial.begin(115200);
    if(!SD.begin(SS)){
        Serial.println("Card Mount Failed");
        return;
    }
    uint8_t cardType = SD.cardType();

    if(cardType == CARD_NONE){
        Serial.println("No SD card attached");
        return;
    }

    Serial.print("SD Card Type: ");
    if(cardType == CARD_MMC){
        Serial.println("MMC");
    } else if(cardType == CARD_SD){
        Serial.println("SDSC");
    } else if(cardType == CARD_SDHC){
        Serial.println("SDHC");
    } else {
        Serial.println("UNKNOWN");
    }

    uint64_t cardSize = SD.cardSize() / (1024 * 1024);
    Serial.printf("SD Card Size: %lluMB\n", cardSize);

    listDir(SD, "/", 0);
    createDir(SD, "/mydir");
    listDir(SD, "/", 0);
    removeDir(SD, "/mydir");
    listDir(SD, "/", 2);
    writeFile(SD, "/hello.txt", "Hello ");
    appendFile(SD, "/hello.txt", "World!\n");
    readFile(SD, "/hello.txt");
    deleteFile(SD, "/foo.txt");
    renameFile(SD, "/hello.txt", "/foo.txt");
    readFile(SD, "/foo.txt");
    testFileIO(SD, "/test.txt");
    Serial.printf("Total space: %lluMB\n", SD.totalBytes() / (1024 * 1024));
    Serial.printf("Used space: %lluMB\n", SD.usedBytes() / (1024 * 1024));
}

void loop(){

}
  • 结果:如读写卡测试正常,将会打印类似于如下TF卡的类型和存储空间等测试信息。
DFR0651 TF app2.png


使用电源控制管脚实现系统的超低功耗

DFR0651 EN App1(CH).png


  • 在使用Gravity: 模拟pH计V2作户外水质监控时,pH计实际仅在需要测量时短暂通电,然后关闭即可。假如根据水质监测的要求,需要每隔10分钟测量一次pH值,每次系统唤醒->测量->数据记录->休眠花费1s,将传感器仅在需要时通电,置于间歇的工作状态,可极大降低系统功耗。在这里pH计功耗约为20mW,通过间歇工作可将其平均功耗降到原来的1/600,即33uW,并随着测量间隔变长而进一步降低。D0可通过杜邦线连接到EN1,通过将其拉低来关断pH计的电源。


pinMode(D0,OUTPUT);      //将D0配置为输出
digitalWrite(D0,HIGH);    //将D0输出高电平,打开pH计的供电
//读取pH计值,并将数据记录到FLASH或TF卡中
digitalWrite(D0,LOW);    //将D0输出低电平,关断pH计的供电

常见问题

Q1. 为什么5V端口测出不是5V电压?

A. 5V端口供电由主板提供,由于主控板通常不带有升压功能,当主板由太阳能或者电池供电时,5V端口悬空,无法对外供电;只有当主板由外部6V-24V或者USB供电时,5V端口才有5V电压输出对外供电。详情参考DFR0530 TinkerNode NB-IoT 物联网开发板

更多问题及有趣的应用,可以 访问论坛 进行查阅或发帖。


更多


DFshopping car1.png 商城购买链接

个人工具
名字空间

变换
操作
导航
工具箱