模拟PH计

概述

还在为没有一款价格低廉、使用方便的pH计而发愁吗?我们推出了一款专门为Arduino控制器设计的模拟pH计,具有连线简单、方便实用等特点。板载电源指示灯、BNC接口和PH2.0接口。使用时,将pH传感器接到板载BNC接口,将板载PH2.0接口连接到Arduino控制器的模拟口,通过程序控制,您可以非常方便的测量溶液的pH值。 传感器的电极采用玻璃电极和参比电极组合在一起的塑壳不可填充式复合电极,是PH计测量元件,用来测量水溶液中的氢离子活度,即PH值。 该传感器附带黑色厚实包装盒,内附黑色优质海绵垫,不仅充分保护元器件,而且大方美观,附送PH复合电极使用说明书。

注意:为保证测量精度,建议使用校准液对pH计定期校准,以防止出现较大误差。一般半年校准一次,如果测量的溶液中含有较多杂质,建议增加校准次数!

技术指标

pH电极特性

该映射表仅为探头电压输出,非模拟端电压输出。 电极输出为毫伏级,与pH值的关系如下(25℃):

pH计的使用

连接图

使用步骤

注意:

(1)将各个设备按照图示方式连接,即:pH电极连接到pH meter电路板的BNC接口,然后用模拟连接线,将pH meter电路板连接到Arduino主控器的模拟口2。对Arduino主控器供电后,可以看到pH meter电路板的蓝色指示灯变亮。

(2)对Arduino主控器烧写样例代码。

(3)将pH电极插入到pH值为7.00的标准溶液中,或者直接短接BNC接口的两个输入,打开Arduino IDE的串口监视器,可以看到当前打印出的pH值,误差不会超过0.3。记录下此时打印的值,然后与7.00相比,把差值修改到程序中的Offset处(差值 = 标准值(7.0) - 打印值)。比如,打印出的pH值为6.88,则差值为0.12,则在样例程序中把#define Offset 0.00改成#define Offset 0.12。

(4)将pH电极插入pH值为4.00的校准液中,等待一分钟后,调整增益电位器,使打印出的pH值尽量稳定在4.00左右。此时,酸性段校准已经完成,您可以测试酸性溶液的pH值。

注意:测量其他溶液时,必须清洗电极。

(5)依靠pH电极自身的线性特性,经过以上的校准,可以直接测量碱性溶液的pH值,但如果您想获得更好的精度,建议重新校准。碱性段校准采用pH值为9.18的标准液,同样是调节增益电位器,使之稳定在9.18左右。经过校准,此时您可以测量碱性溶液的pH值了。

样例代码

下载样例代码后,打开Arduino IDE的串口监视器,即可看到结果。

/*
 # This sample code is used to test the pH meter V1.0.
 # Editor : YouYou
 # Ver    : 1.0
 # Product: analog pH meter
 # SKU    : SEN0161
*/
#define SensorPin A2            //pH meter Analog output to Arduino Analog Input 0
#define Offset 0.00            //deviation compensate
#define LED 13
#define samplingInterval 20
#define printInterval 800
#define ArrayLenth  40    //times of collection
int pHArray[ArrayLenth];   //Store the average value of the sensor feedback
int pHArrayIndex=0;
void setup(void)
{
  pinMode(LED,OUTPUT);
  Serial.begin(9600);
  Serial.println("pH meter experiment!");    //Test the serial monitor
}
void loop(void)
{
  static unsigned long samplingTime = millis();
  static unsigned long printTime = millis();
  static float pHValue,voltage;
  if(millis()-samplingTime > samplingInterval)
  {
      pHArray[pHArrayIndex++]=analogRead(SensorPin);
      if(pHArrayIndex==ArrayLenth)pHArrayIndex=0;
      voltage = avergearray(pHArray, ArrayLenth)*5.0/1024;
      pHValue = 3.5*voltage+Offset;
      samplingTime=millis();
  }
  if(millis() - printTime > printInterval)   //Every 800 milliseconds, print a numerical, convert the state of the LED indicator
  {
    Serial.print("Voltage:");
        Serial.print(voltage,2);
        Serial.print("    pH value: ");
    Serial.println(pHValue,2);
        digitalWrite(LED,digitalRead(LED)^1);
        printTime=millis();
  }
}
double avergearray(int* arr, int number){
  int i;
  int max,min;
  double avg;
  long amount=0;
  if(number<=0){
    Serial.println("Error number for the array to avraging!/n");
    return 0;
  }
  if(number<5){   //less than 5, calculated directly statistics
    for(i=0;i<number;i++){
      amount+=arr[i];
    }
    avg = amount/number;
    return avg;
  }else{
    if(arr[0]<arr[1]){
      min = arr[0];max=arr[1];
    }
    else{
      min=arr[1];max=arr[0];
    }
    for(i=2;i<number;i++){
      if(arr[i]<min){
        amount+=min;        //arr<min
        min=arr[i];
      }else {
        if(arr[i]>max){
          amount+=max;    //arr>max
          max=arr[i];
        }else{
          amount+=arr[i]; //min<=arr<=max
        }
      }//if
    }//for
    avg = (double)amount/(number-2);
  }//if
  return avg;
}

Mind+(基于Scratch3.0)图形化编程

1、下载及安装软件。下载地址:https://www.mindplus.cc 详细教程:Mind+基础wiki教程-软件下载安装 2、切换到“上传模式”。 详细教程:Mind+基础wiki教程-上传模式编程流程 3、“扩展”中选择“主控板”中的“Arduino Uno”,“传感器”中加载“模拟PH计”。 详细教程:Mind+基础wiki教程-加载扩展库流程 4、进行编程,程序如下图: 5、菜单“连接设备”,“上传到设备” 6、程序上传完毕后,打开串口即可看到数据输出。详细教程:Mind+基础wiki教程-串口打印

结果

打开串口监视器,将波特率调整到9600,在串口中可以读取PH计所测水源的PH值。

维护及注意事项

相关文档

DFshopping_car1.png pH meter(SKU:SEN0161)商城购链接