(SKU:SEN0244)模拟TDS传感器

来自DFRobot Product Wiki
跳转至: 导航搜索
模拟TDS传感器

目录

简介

TDS(Total Dissolved Solids),中文名总溶解固体,又称溶解性固体总量,表明1升水中溶有多少毫克溶解性固体。一般来说,TDS值越高,表示水中含有的溶解物越多,水就越不洁净。因此,TDS值的大小,可作为反映水的洁净程度的依据之一。
常用的TDS检测设备为TDS笔,虽然价格低廉,简单易用,但不能把数据传给控制系统,做长时间的在线监测,并做水质状况分析。使用专门的仪器,虽然能传数据,精度也高,但价格很贵。为此,我们专门推出了这款arduino兼容的TDS传感器,连接至arduino控制器后,就可用于测量水的TDS值。
该产品专为arduino设计,即插即用,使用简单方便。3.3~5.5V的宽电压供电,0~2.3V的模拟信号输出,使得这款产品兼容5V、3.3V控制系统,能非常方便的接到现成的控制系统中使用。测量用的激励源采用交流信号,可有效防止探头极化,延长探头寿命的同时,也增加了输出信号的稳定性。TDS探头为防水探头,可长期浸入水中测量。
该产品可应用于生活用水、水培等领域的水质检测。有了这个传感器,就可轻松DIY一套TDS检测仪了,轻松检测水的洁净程度,为你的水质把好关。

产品参数

信号转接板

  • 输入电压:3.3~5.5V
  • 输出信号:0~2.3V
  • 工作电流: 3~6mA
  • TDS测量范围:0~1000ppm
  • TDS测量精度:±10% F.S.(25℃)
  • 尺寸:42*32mm
  • 模块接口:PH2.0-3P
  • 电极接口:XH2.54-2P

TDS探头

  • 探针数量:2
  • 总体长度:83cm
  • 连线接口:XH2.54-2P
  • 颜色:黑色
  • 其他:防水探头


引脚说明

TDS传感器信号转接板管脚定义
TDS传感器信号转接板管脚定义
标号 名称 功能描述
1 - 电源输入负极
2 + 电源输入正极(3.3~5.5V)
3 A 模拟信号输出端(0~2.3V)
4 Probe TDS探头接口
5 LED 电源指示灯


使用教程

本教程将演示如何使用这款产品测量水的TDS值。请认真阅读本教程,注意步骤与细节。

Warning yellow.png
  • TDS探头不能用于55℃以上的水中。
  • TDS探头放置位置不能太靠近容器边缘,否则会影响示数。
  • TDS探头头部与导线为防水,可浸入水中,但连线接口处与信号转接板不防水,请注意使用。

准备

  • 硬件
    • 1 x ArduinoUNO控制板(或类似的控制板)
    • 1 x TDS传感器信号转接板
    • 1 x TDS探头
    • 1 x 被测溶液
    • 1 x 3PIN传感器连接线(或若干 杜邦线)
  • 软件

接线图

如下图所示,先将TDS探头接到信号转接板上,再将信号转接板与Arduino主控器连接。连线完毕后,上传样例代码至Arduino主控器。

SEN0244 application 0.png


样例代码

/***************************************************
 DFRobot Gravity: Analog TDS Sensor / Meter For Arduino
 <https://www.dfrobot.com/wiki/index.php/Gravity:_Analog_TDS_Sensor_/_Meter_For_Arduino_SKU:_SEN0244>
 
 Created 2017-8-22
 By Jason <jason.ling@dfrobot.com@dfrobot.com>
 
 GNU Lesser General Public License.
 See <http://www.gnu.org/licenses/> for details.
 All above must be included in any redistribution
 
 /***********Notice and Trouble shooting***************
 1. This code is tested on Arduino Uno and Leonardo with Arduino IDE 1.0.5 r2 and 1.8.2.
 2. More details, please click this link: <https://www.dfrobot.com/wiki/index.php/Gravity:_Analog_TDS_Sensor_/_Meter_For_Arduino_SKU:_SEN0244>
 ****************************************************/

#define TdsSensorPin A1
#define VREF 5.0      // analog reference voltage(Volt) of the ADC
#define SCOUNT  30           // sum of sample point
int analogBuffer[SCOUNT];    // store the analog value in the array, read from ADC
int analogBufferTemp[SCOUNT];
int analogBufferIndex = 0,copyIndex = 0;
float averageVoltage = 0,tdsValue = 0,temperature = 25;

void setup()
{
    Serial.begin(115200);
    pinMode(TdsSensorPin,INPUT);
}

void loop()
{
   static unsigned long analogSampleTimepoint = millis();
   if(millis()-analogSampleTimepoint > 40U)     //every 40 milliseconds,read the analog value from the ADC
   {
     analogSampleTimepoint = millis();
     analogBuffer[analogBufferIndex] = analogRead(TdsSensorPin);    //read the analog value and store into the buffer
     analogBufferIndex++;
     if(analogBufferIndex == SCOUNT) 
         analogBufferIndex = 0;
   }   
   static unsigned long printTimepoint = millis();
   if(millis()-printTimepoint > 800U)
   {
      printTimepoint = millis();
      for(copyIndex=0;copyIndex<SCOUNT;copyIndex++)
        analogBufferTemp[copyIndex]= analogBuffer[copyIndex];
      averageVoltage = getMedianNum(analogBufferTemp,SCOUNT) * (float)VREF / 1024.0; // read the analog value more stable by the median filtering algorithm, and convert to voltage value
      float compensationCoefficient=1.0+0.02*(temperature-25.0);    //temperature compensation formula: fFinalResult(25^C) = fFinalResult(current)/(1.0+0.02*(fTP-25.0));
      float compensationVolatge=averageVoltage/compensationCoefficient;  //temperature compensation
      tdsValue=(133.42*compensationVolatge*compensationVolatge*compensationVolatge - 255.86*compensationVolatge*compensationVolatge + 857.39*compensationVolatge)*0.5; //convert voltage value to tds value
      //Serial.print("voltage:");
      //Serial.print(averageVoltage,2);
      //Serial.print("V   ");
      Serial.print("TDS Value:");
      Serial.print(tdsValue,0);
      Serial.println("ppm");
   }
}
int getMedianNum(int bArray[], int iFilterLen) 
{
      int bTab[iFilterLen];
      for (byte i = 0; i<iFilterLen; i++)
	  bTab[i] = bArray[i];
      int i, j, bTemp;
      for (j = 0; j < iFilterLen - 1; j++) 
      {
	  for (i = 0; i < iFilterLen - j - 1; i++) 
          {
	    if (bTab[i] > bTab[i + 1]) 
            {
		bTemp = bTab[i];
	        bTab[i] = bTab[i + 1];
		bTab[i + 1] = bTemp;
	     }
	  }
      }
      if ((iFilterLen & 1) > 0)
	bTemp = bTab[(iFilterLen - 1) / 2];
      else
	bTemp = (bTab[iFilterLen / 2] + bTab[iFilterLen / 2 - 1]) / 2;
      return bTemp;
}

结果

样例代码上传完毕后,打开Arduino IDE的串口监视器。将TDS探头插入需要测量的水中,轻轻搅拌几下,观察串口监视器上面打印的数值,此数值就是水的TDS值。如下图所示。

TdsShowNumber.png


常见问题

问:该传感器有温度补偿功能吗? 怎么进行温度补偿?

答:TDS探头不带温度补偿,但样例代码中预留了温度补偿算法,没有温度传感器时,temperature变量默认25℃。您可以外接一款防水的温度传感器,将温度传感器数值更新temperature变量,即可进行自动温度补偿。


更多问题及有趣的应用,可以 访问论坛 进行查阅或发帖。


更多

  • 有趣的应用链接
  • 相关下载链接
  • 推荐阅读链接



DFshopping car1.png [Link DFRobot商城购买链接]

个人工具
名字空间

变换
操作
导航
工具箱